среда, 5 августа 2009 г.

Как управлять IContextMenu, часть 2 – показ контекстного меню

Это перевод How to host an IContextMenu, part 2 - Displaying the context menu. Автор: Реймонд Чен.

Вместо вызова фиксированного действия, мы попросим пользователя выбрать пункт из меню и вызовем выбранное действие.

Сделайте такие изменения в нашей функции FormContextPopup:
procedure TForm22.FormContextPopup(Sender: TObject; MousePos: TPoint; var Handled: Boolean);
const
  SCRATCH_QCM_FIRST = 1;
  SCRATCH_QCM_LAST  = $7FFF;
var
  pcm: IContextMenu;
  Menu: HMENU;
  Info: TCMInvokeCommandInfoEx;
  Pt: TPoint;
  iCmd: Integer;
begin
  Handled := True;

  Pt := MousePos;
  if (Pt.X = -1) and (Pt.Y = -1) then
  begin
    Pt.X := 0;
    Pt.Y := 0;
  end;
  Windows.ClientToScreen(Handle, Pt);

  if SUCCEEDED(GetUIObjectOfFile(Handle, 'C:\Windows\clock.avi', IID_IContextMenu, pcm)) then
  try
    Menu := CreatePopupMenu;
    if Menu <> 0 then
    try
      if SUCCEEDED(pcm.QueryContextMenu(Menu, 0, SCRATCH_QCM_FIRST, SCRATCH_QCM_LAST, CMF_NORMAL)) then
      begin
        iCmd := Integer(TrackPopupMenuEx(Menu, TPM_RETURNCMD, Pt.X, Pt.y, Handle, nil));
        if iCmd > 0 then
        begin
          FillChar(Info, SizeOf(Info), 0);
          Info.cbSize := SizeOf(info);
          Info.hwnd := Handle;
          Info.fMask := CMIC_MASK_UNICODE;
          Info.lpVerb  := MAKEINTRESOURCEA(iCmd - SCRATCH_QCM_FIRST);
          Info.lpVerbW := MAKEINTRESOURCEW(iCmd - SCRATCH_QCM_FIRST);
          Info.nShow := SW_SHOWNORMAL;
          SetLastError(pcm.InvokeCommand(PCMInvokeCommandInfo(@Info)^));
          if GetLastError <> 0 then
            RaiseLastOSError;
        end;

      end;
    finally
      DestroyMenu(Menu);
    end;
  finally
    pcm := nil;
  end;
end;
Ну, первый подводный камень за нас обрабатывает Delphi, передавая нам готовые координаты в MousePos.

Изменение с Pt обрабатывает второй подводный камень: специальная обработка для контекстных меню, вызванных с клавиатуры. Когда мы получаем контекстное меню, вызванное с клавиатуры, мы вызываем его с координатами (0, 0) в нашем окне. Это позволяет показать меню в относительно разумной позиции (ну, если бы мы работали с каким-нибудь списком, то лучше бы нам было показать контекстное меню рядом с текущим выбранным элементом).

Третий изменённый блок и делает собственно работу, о которой мы говорили: показывает контекстное меню пользователю, обрабатывает результат и вызывает действие.

Вы, несомненно, знакомы с функцией TrackPopupMenuEx. Сейчас мы использовали флаг TPS_RETURNCMD, чтобы указать, что выбранный пользователем пункт меню должен быть возвращён функцией, вместо того, чтобы быть отправленным в сообщении WM_COMMAND нашему окну.

Тут важно ещё подчеркнуть, что SCRATCH_QCM_FIRST рана 1, а не нулю. Если бы она была бы равна нулю – мы не смогли бы отличить ситуации с выбором пункта меню и отмены меню пользователем.

Как только мы убедились, что пользователь выбрал пункт меню, мы заполняем запись TCMInvokeCommandInfoEx, указывая выбранное пользователем действие в двух полях и указывая точку вызова через ptInvoke.

Заметьте, что когда вы вызываете команду по ID меню, вы обязаны указать смещение пункта меню относительно к стартовой точке, переданной в IContextMenu.QueryContextMenu. Вот почему мы сначала вычитаем SCRATCH_QCM_FIRST.

Когда вы запустите эту программу, вы увидите, что не все вещи работают как надо. Больше всего бросается в глаза, что пункты “Открыть с помощью” и “Отправить” не работают, но есть также и несколько других, менее заметных, багов. Мы разберёмся с ними в ближайшие несколько дней.

Комментариев нет:

Отправить комментарий

Можно использовать некоторые HTML-теги, например:

<b>Жирный</b>
<i>Курсив</i>
<a href="http://www.example.com/">Ссылка</a>

Вам необязательно регистрироваться для комментирования - для этого просто выберите из списка "Анонимный" (для анонимного комментария) или "Имя/URL" (для указания вашего имени и ссылки на сайт). Все прочие варианты потребуют от вас входа в вашу учётку.

Пожалуйста, по возможности используйте "Имя/URL" вместо "Анонимный". URL можно просто не указывать.

Ваше сообщение может быть помечено как спам спам-фильтром - не волнуйтесь, оно появится после проверки администратором.

Примечание. Отправлять комментарии могут только участники этого блога.